# Quadratic_Regression_Inflection
input length = 100;
input ROClength = 5;
input crossingType = {default above, below};
def bn = BarNumber();
def lastBar = HighestAll(if IsNaN(close) then 0 else bn);
def x = bn;
def y = close;
def n = RoundUp((length / (Round(AbsValue(Average(((close / close[ROClength] - 1) * 100), ROClength)), 0))), 0);
# calculate sumation values
def startBar = lastBar - (n - 1);
def sumX = if bn < startBar then 0 else x + sumX[1];
def sumY = if bn < startBar then 0 else y + sumY[1];
def sumX2 = if bn < startBar then 0 else Power(x, 2) + sumX2[1];
def sumX3 = if bn < startBar then 0 else Power(x, 3) + sumX3[1];
def sumX4 = if bn < startBar then 0 else Power(x, 4) + sumX4[1];
def sumXY = if bn < startBar then 0 else x * y + sumXY[1];
def sumX2Y = if bn < startBar then 0 else Power(x, 2) * y + sumX2Y[1];
# intermediary calculations
def xx = sumX2 - Power(sumX, 2) / n;
def xy = sumXY - (sumX * sumY / n);
def xx2 = sumX3 - (sumX2 * sumX / n);
def x2y = sumX2Y - (sumX2 * sumY / n);
def x2x2 = sumX4 - (Power(sumX2, 2) / n);
# calculate coefficients for the quadratic equation
def a0 = (x2y * xx - xy * xx2) / (xx * x2x2 - Power(xx2, 2));
def b0 = (xy * x2x2 - x2y * xx2) / (xx * x2x2 - Power(xx2, 2));
def c0 = sumY / n - b0 * sumX / n - a0 * sumX2 / n;
# for a, b, and c use the final value on the last bar of the chart for all calculations
def a = GetValue(a0, bn - lastBar);
def b = GetValue(b0, bn - lastBar);
def c = GetValue(c0, bn - lastBar);
# calculate and plot parabola and slope inflection point
plot parabola = if bn < startBar then Double.NaN else a * Power(x, 2) + b * x + c;
def zero = 0;
def slope = if bn < startBar then Double.NaN else (2 * a * x) + b;
plot crossing = Crosses(slope, zero, CrossingDirection.ANY);
crossing.SetPaintingStrategy(PaintingStrategy.BOOLEAN_POINTS);
AddLabel(yes, slope, Color.BLUE);
Alert(slope[0] > 0 and slope[1] < 0, "Slope Crosses Zero!", Alert.BAR, Sound.Ding);