Keltner Channel Scan

This is a great question. Very well explained and you provided your own code. Love this.

Convert to Exponential Average

Let’s begin with your very last request. The middle band should be a 20 period Exponential Moving Average. As your code exists, that middle band is a Simple Moving Average:

def average = Average(price, length);

So we first need to change that to get you the Exponential Moving Average you require:

def average = ExpAverage(price, length);

There, that was simple wasn’t it?

Does it work?

The bad news is that your code is missing an important piece. See attached screenshot. I have added your code as a lower study on the chart. I have marked the various signals on the chart generated by your code. I see only one valid signal.

At this point I can either wait for you to provide more details or I can make some assumptions and proceed with the solution. I choose the later. I will assume that when you say:

“stocks that have pierced through the lower keltner channel”

What you mean is that prices should be above the lower band leading up to the pierce. While at the same time the bar that pierces should have opened above the lower band.

The Fix

So we will revise your code to fit that:

input factor = 1.5;
input length = 20;
input price = close;
def shift = factor * Average(TrueRange(high, close, low), length);
def average = ExpAverage(price, length);
def Avg = average;
def Upper_Band = average + shift;
def Lower_Band = average – shift;
def previousBarAbove = low[1] > Lower_Band;
def piercingBar = open > Lower_Band and low < Lower_Band and close > Lower_Band;
plot scan = previousBarAbove and piercingBar;

Second screenshot shows the improved version. Also note in this second screenshot I am using a modified version of the Keltner Channel that comes with Thinkorswim. The standard version uses a simple moving average so I modified one to use the exponential moving average. This ensures we can see on the chart exactly what is taking place in the scan.

Code Review

Notice the modifications I made to your code. I break out the price pattern into the smallest individual pieces. We have previousBarAbove as the first piece and piercingBar as the second. This makes the code much easier to read and debug. You can plot those pieces individually to see what each one is doing. Just change the def to plot to display them on the chart.

This also makes it much easier to modify the specifications. Let’s say you need to have two bars above the lower band before the pierce, instead of just one:

plot scan = previousBarAbove and previousBarAbove[1] and piercingBar;

The Hourly Scan

Now, how about that hourly scan?

“at least 1 hourly bar’s range was outside of the lower channel within the last 2 days (or 14 bars)”

Once again I have to make an assumption here. You used the term “outside the lower channel”, while the only options are to be above or below. We cannot be outside a single line. So I will interpret this to mean you want the range of one hourly bar in the past 14 to be “outside” the Keltner channel. More specifically, below the lower band (because outside the channel could also mean above the upper band).

Ok, so we do the same as we have for the daily, with the added condition that the high of any of the previous 14 bars (excluding the previous) should be below the lower band. Why do we exclude the previous? Because that is the first condition we have for the daily scan (previousBarAbove).

Modified Code for Hourly

So now we have this for the hourly scan:

input factor = 1.5;
input length = 20;
input price = close;
def shift = factor * Average(TrueRange(high, close, low), length);
def average = ExpAverage(price, length);
def Avg = average;
def Upper_Band = average + shift;
def Lower_Band = average – shift;
def previousBarAbove = low[1] > Lower_Band;
def piercingBar = open > Lower_Band and low < Lower_Band and close > Lower_Band;
def belowLowerBand = high < Lower_Band;
plot scan = previousBarAbove and piercingBar and Highest(belowLowerBand[1], 14) > 0;

What the Heck is That?

I will take some time to explain. I have only added one line of code. It evaluates to True when the high of a bar is below the lower band. Which means it is completely outside of the Keltner channel, below the lower band. This true/false variable, converts to a numeric value of 1/0 automatically. So we only need to check of that variable has been true (value == 1) within the last 14 bars (excluding the current bar). We do this using a method named Highest(). This checks for the highest value of the variable within the last 14 bars. We just need to have one of those bars to be true (value == 1) in order to tigger that condition.

Third screenshot shows the result. I left the chart set to daily because it makes it easier for folks to go back and check their own charts. This pattern will be detected on any time frame you apply it to.

Have fun!

Pete,

You’re a legend man.  Thank you for explaining everything in depth.  I’m in the beginning stages of learning how to use thinkscript, and I’ve found this website to be my best guide.

The daily scan is exactly what I was looking for.  The hourly scan isn’t quite giving me the type of results I had in my head.  I tried to edit the code a little bit to scan for charts that meet this criteria: 1 bar closes below lower band, next bar closes above the lower band (which would be better described as a breakout bar rather than a piercing bar), and then I added 2 more bars.  The first closes above the lower band and the second has a low above the lower band.  I defined them as-

def followingBarAbove = high[1] > Lower_Band and close[1] > Lower_Band;
def followingBarHolds = low > Lower_Band;

I’m pretty sure the scan is giving me what I am looking for, but I was hoping you could take a look and let me know what you think or anything you would change.

Here’s the code:

input factor = 1.5;
input length = 20;
input price = close;
def shift = factor * Average(TrueRange(high, close, low), length);
def average = ExpAverage(price, length);
def Avg = average;
def Upper_Band = average + shift;
def Lower_Band = average – shift;
def previousBarBelow = close[3] < Lower_Band;
def piercingBar = high[2] > Lower_Band and low[2] < Lower_Band and close[2] > Lower_Band;
def followingBarAbove = high[1] > Lower_Band and close[1] > Lower_Band;
def followingBarHolds = low > Lower_Band;
def belowLowerBand = high < Lower_Band;
plot scan = previousBarBelow and piercingBar and followingBarAbove and followingBarHolds and Highest(belowLowerBand[1], 14) > 0;

Thanks again Pete.